module Z74X49H 
title 'Seven-Segment_Decoder 
J. Wakerly, Micro Design Resources, Inc.' 
"Z74X49H device 'P16L8'; 

" Input pins 
A, B, C, D                  pin 1, 2, 3, 4; 
!BI                         pin 5;

" Output pins 
SEGA, SEGB, SEGC, SEGD      pin 19, 18, 17, 16 istype 'com'; 
SEGE, SEGF, SEGG            pin 15, 14, 13     istype 'com';

" Set definitions 
DIGITIN = [D,C,B,A]; 
SEGOUT = [SEGA,SEGB,SEGC,SEGD,SEGE,SEGF,SEGG];

" Segment encodings for digits 
DIG0 = [1,1,1,1,1,1,0];  " 0 
DIG1 = [0,1,1,0,0,0,0];  " 1 
DIG2 = [1,1,0,1,1,0,1];  " 2 
DIG3 = [1,1,1,1,0,0,1];  " 3 
DIG4 = [0,1,1,0,0,1,1];  " 4 
DIG5 = [1,0,1,1,0,1,1];  " 5 
DIG6 = [1,0,1,1,1,1,1];  " 6  'tail' included 
DIG7 = [1,1,1,0,0,0,0];  " 7 
DIG8 = [1,1,1,1,1,1,1];  " 8 
DIG9 = [1,1,1,1,0,1,1];  " 9  'tail' included 
DIGA = [1,1,1,0,1,1,1];  " A 
DIGB = [0,0,1,1,1,1,1];  " b 
DIGC = [1,0,0,1,1,1,0];  " C 
DIGD = [0,1,1,1,1,0,1];  " d 
DIGE = [1,0,0,1,1,1,1];  " E 
DIGF = [1,0,0,0,1,1,1];  " F

equations

SEGOUT = !BI & ( (DIGITIN ==  0) & DIG0 # (DIGITIN ==  1) & DIG1
               # (DIGITIN ==  2) & DIG2 # (DIGITIN ==  3) & DIG3
               # (DIGITIN ==  4) & DIG4 # (DIGITIN ==  5) & DIG5
               # (DIGITIN ==  6) & DIG6 # (DIGITIN ==  7) & DIG7
               # (DIGITIN ==  8) & DIG8 # (DIGITIN ==  9) & DIG9
               # (DIGITIN == 10) & DIGA # (DIGITIN == 11) & DIGB
               # (DIGITIN == 12) & DIGC # (DIGITIN == 13) & DIGD
               # (DIGITIN == 14) & DIGE # (DIGITIN == 15) & DIGF );
end Z74X49H